import processing.opengl.*;


	
	public static final class Point {
		public float x,y,z;
		public float vx,vy,vz;
		public float ax,ay,az;
		public float nx,ny,nz;
		public float weight=0.01f;
		public Point(float x_in, float y_in, float z_in) {
			x=x_in;
			y=y_in;
			z=z_in;
		}
	}
	
	public static final class Link {
		final int a,b;
		final float gap;
		public Link(int a_in, int b_in) {
			a=a_in;
			b=b_in;
			Point pa=points[a_in];
			Point pb=points[b_in];
			float dx=pa.x-pb.x;
			float dy=pa.y-pb.y;
			float dz=pa.z-pb.z;
			gap=(float)Math.sqrt(dx*dx+dy*dy+dz*dz);
		}
	}
	
	public static final class Triangle {
		final int a,b,c;
		public Triangle(int a_in, int b_in, int c_in) {
			a=a_in;
			b=b_in;
			c=c_in;
		}
	}
	
	static Point[] points; 
	static Link[] links; 
	static Triangle[] triangles; 

	void setup() {
		size(640,480,OPENGL);
		stroke(155,0,0);
		addMouseWheelListener(new java.awt.event.MouseWheelListener() { 
		    public void mouseWheelMoved(java.awt.event.MouseWheelEvent evt) { 
//		      zoom=Math.max(8,zoom*(8+evt.getWheelRotation())>>3);
		  }}); 

//		generate_resources();
		reset();
	}
	
	static void reset() {

		final int gsize=32;
		final int wi = 8;
		points=new Point[wi*wi];
		links=new Link[wi*(wi-1)*2+(wi-1)*(wi-1)*2];
		triangles=new Triangle[(wi-1)*(wi-1)*2];

		for (int y=0,i=0,l=0,t=0;y<wi;y++) {
			for (int x=0;x<wi;x++,i++) {
				points[i]=new Point(x*gsize-(wi*gsize/2), y*gsize, 0);
				if (x>0) {
					links[l++]=new Link(i,i-1);
				}
				if (y>0) {
					links[l++]=new Link(i,i-wi);
					if (x>0) {
						links[l++]=new Link(i-wi-1,i);
						links[l++]=new Link(i-wi,i-1);
						triangles[t++]=new Triangle(i-wi-1,i-wi,i-1);
						triangles[t++]=new Triangle(i-1,i-wi,i);
					}
				}
			}
		}
		
		//Fixed points
		points[0].weight=0;
		points[wi-1].weight=0;
		
	}
	
	//Wind
	static float wx=0,wy=0;
	//Rotation
	static float rx=0,rz=0;
	
	
	public void update() {
		if (mousePressed) {
			if (mouseButton==LEFT) {
				wx=(mouseX-(width>>1))/10f;
				wy=(mouseY-(height>>1))/10f;
			}
			else if (mouseButton==RIGHT) {
				rx=mouseY/40f;
				rz=mouseX/40f;
			}
		}
                for (int pi=0;pi<points.length;pi++) {
                  Point p=points[pi];
			
			float wind_force=(wx*p.nx+wy*p.nz)/32f;
			
			p.ax=wind_force*p.nx;
			p.ay=wind_force*p.ny+p.weight;
			p.az=wind_force*p.nz;
		}
                for (int li=0;li<links.length;li++) {
                  Link l=links[li];
			Point pa=points[l.a];
			Point pb=points[l.b];
			final float gap;
			final float dx=pb.x-pa.x;
			final float dy=pb.y-pa.y;
			final float dz=pb.z-pa.z;
			gap=(float)Math.sqrt(dx*dx+dy*dy+dz*dz);
			
			final float tension=0.3f;
			final float compression=0.1f;
			
			final float motion=(gap-l.gap)*(gap<l.gap ? tension : compression)/gap;
			if (pa.weight>0) {
				pa.ax+=dx*motion;
				pa.ay+=dy*motion;
				pa.az+=dz*motion;
			}
			if (pb.weight>0) {
				pb.ax-=dx*motion;
				pb.ay-=dy*motion;
				pb.az-=dz*motion;
			}
		}
		final float friction = 0.95f;
                for (int pi=0;pi<points.length;pi++) {
                  Point p=points[pi];
			if (p.weight<=0) continue;
			p.vx+=p.ax;
			p.vy+=p.ay;
			p.vz+=p.az;
			p.vx*=friction;
			p.vy*=friction;
			p.vz*=friction;
			p.x+=p.vx;
			p.y+=p.vy;
			p.z+=p.vz;
			p.nx=0;
			p.ny=0;
			p.nz=0;
		}
                for (int ti=0;ti<triangles.length;ti++) {
                  Triangle t=triangles[ti];
			Point pa=points[t.a];
			Point pb=points[t.b];
			Point pc=points[t.c];
			final float bx=pb.x-pa.x;
			final float by=pb.y-pa.y;
			final float bz=pb.z-pa.z;
			final float cx=pc.x-pa.x;
			final float cy=pc.y-pa.y;
			final float cz=pc.z-pa.z;
			final float nx=by*cz-bz*cy;
			final float ny=bz*cx-bx*cz;
			final float nz=bx*cy-by*cx;
			pa.nx+=nx;
			pa.ny+=ny;
			pa.nz+=nz;
			pb.nx+=nx;
			pb.ny+=ny;
			pb.nz+=nz;
			pc.nx+=nx;
			pc.ny+=ny;
			pc.nz+=nz;
		}
                for (int pi=0;pi<points.length;pi++) {
                  Point p=points[pi];
			float n=(float)Math.sqrt(p.nx*p.nx+p.ny*p.ny+p.nz*p.nz);
			p.nx/=n;
			p.ny/=n;
			p.nz/=n;
		}
	}
	public void draw() {
		
		if (keyPressed && key==' ') reset();
		update();
		
		background(0x333333);
		
		pushMatrix();
		translate(width>>1,height>>1,0);
		rotateX(rx);
		rotateY(rz);
		beginShape(TRIANGLES);
for (int ti=0;ti<triangles.length;ti++) {
                  Triangle t=triangles[ti];

			Point pa=points[t.a];
			Point pb=points[t.b];
			Point pc=points[t.c];
			vertex(pa.x,pa.y,pa.z);
			vertex(pb.x,pb.y,pb.z);
			vertex(pc.x,pc.y,pc.z);
		}
		endShape();

		final float nlength=5;
                for (int pi=0;pi<points.length;pi++) {
                  Point p=points[pi];
			line(p.x, p.y, p.z, p.x+p.nx*nlength, p.y+p.ny*nlength, p.z+p.nz*nlength);
		}
		stroke(0xff,0x00,0x00); line(0,0,0,1000,0,0);
		stroke(0x00,0xff,0x00); line(0,0,0,0,1000,0);
		stroke(0x00,0x00,0xff); line(0,0,0,0,0,1000);
		stroke(0x00,0xff,0xff); line(0,0,50,0+wx,0,50+wy);
		stroke(0x66,0x66,0x66);
		popMatrix();
	}